class FunctionGenBox {
  float x, y, w, h;
  float start, duration; //time, in seconds
  float freq;

  FunctionGenBox[] all;
  
  FunctionGenBox(float sze, float freq) {
    this.x = 0;
    this.y = 0;
    this.w = sze;
    this.h = sze;

    this.freq = freq;
    
    this.start = 0;
    this.duration = .01;
  }

  void setAll(FunctionGenBox[] all) {
    this.all = all;
  }
  
  void stepAndRender() {
    float tick = this.duration / this.w; //in seconds per pixel

    fill(255, 100);
    rect(this.x, this.y, this.w, this.h);

    noFill();
    beginShape();
    for(float curx=this.x; curx<this.x + this.w; curx+=5) {
      vertex(curx, constrain(this.y + .15 * this.h *
                             this.getYWithOverlaps(curx) + (this.h /
                                                            2), 
                             this.y,
                             this.y + this.h));
    }
    endShape();

    this.start += tick;         // advance start
  }

  //gets time at a pixel (x is in global space)
  float xToI(float x) {
    return this.start + (this.duration / this.w) * (x - this.x);
  }

  // i is in time
  float getThisY(float i) {         
    return sin(i * TWO_PI * this.freq);
  }

  // x is in global space
  float getYWithOverlaps(float x) {

    float acc = 0.;
    float num = 0;
    for(int i=0; i<this.all.length; i++) {

      // check for x overlap
      if(x >= this.all[i].x && x <= this.all[i].x + this.all[i].w) {
        acc += this.all[i].getThisY(this.all[i].xToI(x));
        num += 1;
      }
    }

    return acc;                 // todo: normalize?

  }

  void moveBy(float dx, float dy) {
    this.x += dx;
    this.y += dy;
  }
}